COMMENT ⊗   VALID 00004 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	{$NOMAIN	"Root" portion of Move (& kin) Interpreters }
C00028 00003	{ Externally defined routines: }
C00031 00004	(* aux routines for motions: forcebits, getMechbits, moveStart, moveEnd, moveRetry *)
C00044 ENDMK
C⊗;
{$NOMAIN	"Root" portion of Move (& kin) Interpreters }

const
	GARMDEV   = 1;			(* device numbers for ARM *)
	VISEDEV   = 6;

	XFORCE = 0B;		(* Force along X direction of C *)
	YFORCE = 1000B;		(*   "	  "   Y	    "	  "  " *)
	ZFORCE = 2000B;		(*   "	  "   Z	    "	  "  " *)
	XMOMENT = 3000B;	(* Moment about X direction of C *)

	nullingcb = 512;		(* control bits for trajectory specs *)
	durlbcb = 64;			(* Duration: lower, upper & exact bounds *)
	destptcb = 8;

(* control bits for trajectory specs: movesegcmd & movehdrcmd *)

	Joint1cb = 1;		(* 1B *)
	Joint2cb = 2;		(* 2B *)
	Joint3cb = 4;		(* 4B *)
	Joint4cb = 8;		(* 10B *)
	Joint5cb = 16;		(* 20B *)
	Joint6cb = 32;		(* 40B *)
	Byptcb = 256;		(* 400B *)


  (* Constants from EDIT *)

  maxLines = 28;
  maxPPLines = 12;
  maxBpts = 25;
  maxTBpts = 20;	(* max could be exceeded by huge case stmnt *)
  listinglength = 2000;	(* Length of Listingarray *)

(* Random type declarations for OMSI/SAIL compatibility *)

type
  byte = 0..255;	(* doesn't really belong here, but... *)
  ascii = char; 
  atext = text;

{ Define all the pointer types here }

vectorp = ↑vector;
transp = ↑trans;
strngp = ↑strng;
eventp = ↑event;
framep = ↑frame;
statementp = ↑statement;
varidefp = ↑varidef;
nodep = ↑node;
pdbp = ↑pdb;
envheaderp = ↑envheader;
enventryp = ↑enventry;
environp = ↑environment;
cmoncbp = ↑cmoncb;
messagep = ↑message;
identp = ↑ident;

(* This one is used whenever a pointer is needed for which the 	*)
(* definition is missing from this file; naturally, all 	*)
(* pointers use the same space 					*)

dump = ↑integer;
token = array[1..4] of integer;		{Uses same space as a token}
cursorp = array[1..4] of integer;	{Ditto, for cursorp}


(* datatype definitions *)

datatypes = (pconstype, varitype, svaltype, vectype, rottype, transtype,
	     frametype, eventtype, strngtype, labeltype, proctype, arraytype,
	     reftype, valtype, cmontype, nulltype, undeftype,
	     dimensiontype, mactype, macargtype, freevartype);

scalar = real;

u = (used,free);
vector = record case u of
	   used: (refcnt: integer; val: array [1..3] of real);
	   free: (next: vectorp);
	 end;

trans = record case u of
	   used: (refcnt: integer; val: array [1..3,1..4] of real);
	   free: (next: transp);
	end;

cstring = packed array [1..10] of ascii;
c4str = packed array [1..4] of ascii;
c5str = packed array [1..5] of ascii;
c20str = packed array [1..20] of ascii;
linestr = packed array [1..130] of ascii;

strng = record
	  next: strngp;
	  ch: cstring;
	end;

event = record
	  next: eventp;		(* all events are on one big list *)
	  count: integer;
	  waitlist: pdbp;
	end;

frame = record
	  vari: varidefp;	(* back pointer to variable name & info *)
	  calcs: nodep;		(* affixment info *)
	  case ftype: boolean of	(* frame = true, device = false *)
  true:	    (valid: integer; val, fdepr: transp; dcntr: integer; dev: framep);
  false:    (mech: integer; case sdev: boolean of
		true: (sdest: real); false: (tdest,appr,depr: transp));
		(* sdev = true for scalar devices, false for frames *)
	end;

ident = record
	    next: identp;
	    length: integer;
	    name: strngp;
	    predefined: varidefp;
	  end;




(* statement definitions *)

stmntypes = (progtype, blocktype, coblocktype, endtype, coendtype,
		fortype, iftype, whiletype, untiltype, casetype,
		calltype, returntype,
		printtype, prompttype, pausetype, aborttype, assigntype,
		signaltype, waittype, enabletype, disabletype, cmtype,
		affixtype, unfixtype,
		movetype,jtmovetype,operatetype,opentype,closetype,centertype,
		floattype, stoptype, retrytype,
		requiretype, definetype, macrotype, commenttype, dimdeftype,
		setbasetype, wristtype, saytype, declaretype, emptytype,
		evaltype, armmagictype);
		(* more??? *)

statement = packed record
		next, last: statementp;
		stlab: varidefp;
		exprs: nodep;	(* any expressions used by this statement *)
		nlines: integer;
		bpt,bad: boolean;
		case stype: stmntypes of

    affixtype,
    unfixtype:	    (frame1, frame2, byvar, atexp: nodep; rigid: boolean);
    signaltype,
    waittype:	    (event: nodep);
    movetype,
    jtmovetype,
    operatetype,
    opentype,
    closetype,
    centertype,
    floattype,
    setbasetype,
    stoptype:	    (cf, clauses: nodep);
    retrytype:	    (rcode, rparent: statementp; olevel: integer);
    wristtype:	    (arm, ff, fvec, tvec: nodep; csys: boolean);
    cmtype:	    (oncond: nodep; conclusion: statementp;
			deferCm, exprCm: boolean; cdef: varidefp);
    enabletype,
    disabletype:    (cmonlab: varidefp);
    armmagictype:   (cmdnum,dev,iargs,oargs: nodep);
		end;



(* auxiliary definitions: variable, etc. *)

varidef = packed record
	    next,dnext: varidefp;
	    name: identp;
	    level: 0..255;	(* environment level *)
	    offset: 0..255;	(* environment offset *)
	    dtype: varidefp;	(* to hold the dimension info *)
	    tbits: 0..15;  (* special type bits: array = 1, proc = 2, ref = 4 & ? *)
	    dbits: 0..15;	(* for use by debugger/interpreter *)
	    case vtype: datatypes of
  arraytype:  (a: nodep);
  proctype:   (p: nodep);
  labeltype,
  cmontype:   (s: statementp);
  mactype:    (mdef: statementp);
  macargtype: (marg: dump);
  pconstype:  (c: nodep);
  dimensiontype: (dim: nodep);
	  end;



(* definition of the ubiquitous NODE record *)

nodetypes = (exprnode, leafnode, listnode, clistnode, colistnode, forvalnode,
		deprnode, viaptnode, apprnode, destnode, byptnode, durnode,
		sfacnode, wobblenode, swtnode, nullingnode, wristnode, cwnode,
		arrivalnode, departingnode,
		ffnode, forcenode, stiffnode, gathernode, cmonnode, errornode,
		calcnode, arraydefnode, bnddefnode, bndvalnode,
		waitlistnode, procdefnode, tlistnode, dimnode, commentnode,
		linearnode, elbownode, shouldernode, flipnode, wrtnode,
		loadnode,velocitynode);

exprtypes =  (	svalop,					(* scalar operators *)
		sltop, sleop, seqop, sgeop, sgtop, sneop,	(* relations *)
		notop, orop, xorop, andop, eqvop,		(* logical *)
		saddop, ssubop, smulop, sdivop, snegop, sabsop, (* scalar ops *)
		sexpop, maxop, minop, intop, idivop, modop,
		sqrtop, logop, expop, timeop,			(* functions *)
		sinop, cosop, tanop, asinop, acosop, atan2op,	(* trig *)
		vdotop, vmagnop, tmagnop,
		vecop,					(* vector operators *)
		vmakeop, unitvop, vaddop, vsubop, crossvop, vnegop,
		svmulop, vsmulop, vsdivop, tvmulop, wrtop,
		tposop, taxisop,
		transop,				(* trans operators *)
		tmakeop, torientop, ttmulop, tvaddop, tvsubop, tinvrtop,
		vsaxwrop, constrop, ftofop, deproachop, fmakeop, vmkfrcop,
		ioop,					(* i/o operators *)
		queryop, inscalarop,
		specop,					(* special operators *)
		arefop, callop, grinchop, macroop, vmop, adcop, dacop, jointop,
		badop,
		addop, subop, negop, mulop, divop, absop); (* for parsing *)

leaftypes = pconstype..strngtype;

reltypes = sltop..sgtop;
forcetypes = (force,absforce,torque,abstorque,angvelocity);

node = record
	next: nodep;
	case ntype: nodetypes of
    exprnode:	(op: exprtypes; arg1, arg2, arg3: nodep; elength: integer);
    leafnode:	(case ltype: leaftypes of
	varitype:  (vari: varidefp; vid: dump);
	pconstype: (cname: varidefp; pcval: nodep);
	svaltype:  (s: scalar; wid: integer);
	vectype:   (v: vectorp);
	transtype: (t: transp);
	strngtype: (length: integer; str: strngp) ); (* also used by commentnodes *)
    arrivalnode:(evar: varidefp);
    wrtnode,
    deprnode,
    apprnode,
    destnode:	(loc: nodep; code: statementp);
    byptnode,
    viaptnode:	(vlist: boolean; via,vclauses: nodep; vcode: statementp);
    durnode:	(durrel: reltypes; durval: nodep);
    velocitynode,
    sfacnode,
    wobblenode,
    swtnode:	(clval: nodep);
    nullingnode,			(* true = nonulling *)
    wristnode,				(*	= don't zero force wrist *)
    cwnode,				(*	= counter_clockwise *)
    elbownode,				(*	= elbow up *)
    shouldernode,			(*	= right shoulder *)
    flipnode,				(*	= don't flip wrist *)
    linearnode:	(notp: boolean);	(*	= linear motion *)
    ffnode:	(ff,cf: nodep; csys, pdef: boolean); (* true = world, false = hand *)
    loadnode:	(loadval,loadvec: nodep; lcsys: boolean); (* lcsys = csys above *)
    forcenode:	(ftype: forcetypes; frel: reltypes; fval, fvec, fframe: nodep);
    stiffnode:	(fv, mv, cocff: nodep);
    gathernode:	(gbits: integer);
    cmonnode:	(cmon: statementp; errhandlerp: boolean);
    errornode:	(eexpr: nodep);
	end;



(* process descriptor blocks & environment record definitions *)

queuetypes = (nullqueue,nowrunning,runqueue,inputqueue,eventqueue,sleepqueue,
		forcewait,devicewait,joinwait,proccall);

pdb = packed record
	nextpdb,next: pdbp;	(* for list of all/active pdb's *)
	level: 0..255;		(* lexical level *)
	mode: 0..255;		(* expression/statement/sub-statement *)
	priority: 0..255;	(* probably never greater than 3? *)
	status: queuetypes;	(* what are we doing *)
	env: envheaderp;
	spc: statementp;	(* current statement *)
	epc: nodep;		(* current expression (if any) *)
	sp: nodep;		(* intermediate value stack *)
	cm: cmoncbp;		(* if we're a cmon point to our definition *)
	mech: framep;		(* current device being used *)
	linenum: integer;	(* used by editor/debugger *)
	 case procp: boolean of	(* true if we're a procedure *)
true:  (opdb: pdbp;		(* pdb to restore when procedure exits *)
	pdef: nodep);		(* procedure definition node *)
false: (evt: eventp;		(* event to signal when process goes away *)
	sdef: statementp);	(* first statement where process was defined *)
      end;


envheader = packed record
	      parent: envheaderp;
	      env: array [0..4] of environp;
	      varcnt: 0..255;		(* # of variables in use ??? *)
		case procp: boolean of  (* true if we're a procedure *)
	true: (proc: nodep);
	false:(block: statementp);
	    end;

enventry = record
	    case etype: datatypes of
  svaltype:  (s: scalar);
  vectype:   (v: vectorp);
  transtype: (t: transp);
  frametype: (f: framep);
  eventtype: (evt: eventp);
  strngtype: (length: integer; str: strngp);
  cmontype:  (c: cmoncbp);
  proctype:  (p: nodep; penv: envheaderp);
  reftype:   (r: enventryp);
  arraytype: (a: envheaderp; bnds: nodep);
	   end;


environment = record
		next: environp;
		vals: array [0..9] of enventryp;
	      end;


cmoncb = record
	   running, enabled: boolean;		(* cmon's status *)
	   cmon: statementp;
	   pdb: pdbp;
	   evt: eventp;
	   fbits: integer;			(* bits for force sensing *)
	   oldcmon: cmoncbp;			(* for debugger *)
	 end;



(* definition of AL-ARM messages *)

msgtypes = (initarmscmd,calibcmd,killarmscmd,wherecmd,
	    abortcmd,stopcmd,movehdrcmd,movesegcmd,
	    centercmd,operatecmd,movedonecmd,signalcmd,
	    setccmd,forcesigcmd,forceoffcmd,biasoncmd,biasoffcmd,setstiffcmd,
	    zerowristcmd,wristcmd,gathercmd,getgathercmd,readadccmd,writedaccmd,
	    errorcmd,floatcmd,setloadcmd,
	    armmagiccmd,realcmd,vectorcmd,transcmd);

errortypes = (noerror,noarmsol,timerr,durerr,toolong,featna,
	      unkmess,srvdead,adcdead,nozind,exjtfc,paslim,nopower,badpot,devbusy,
	      baddev,timout,panicb,nocart,cbound,badparm);

message = record
	   cmd: msgtypes;
	   ok: boolean;
	   case integer of
	1:   (dev, bits, n: integer;
(*	     (dev, bits, n, evt: integer;	(* for arm code version *)
	      evt: eventp;
	      dur: real;
	      case integer of
		1: (v1,v2,v3: real);
		2: (sfac,wobble,pos: real);
		3: (val,angle,mag: real);
		4: (max,min: real);
		5: (error: errortypes));
	2:   (fv1,fv2,fv3,mv1,mv2,mv3: real);	(* may never use these... *)
	3:   (t: array [1..6] of real);
	  end;

interr = record
         case integer of
           0: (i: integer);
	   1: (err,foo: errortypes);
	 end;

listingarray = packed array [0..listinglength] of ascii;


(* global variables *)

var
	(* from EDIT *)
    listing: listingarray;  (* first 150 chars are used by expression editor *)
			    (* next 40 by header & trailer lines *)
{*} cursorStack: array [1..15] of cursorp;	{These are BIG records! }
(*  lbuf: array [1..160] of ascii;
    ppBuf: array [1..100] of ascii; *)
    dum1: array[1..260] of ascii;
    lines: array [1..maxLines] of dump; 
    ppLines: array [1..maxPPLines] of dump;	
(*  marks: array [1..20] of integer;
    reswords: array [0..26] of reswordp;
    idents: array [0..26] of identp;
    macrostack: array [1..10] of tokenp;
    curmacstack: array [1..10] of varidefp;
    screenheight,dispHeight: integer;
    ppBufp,oppBufp,ppOffset,ppSize,nmarks: integer;
    lbufp,cursor,ocur,cursorLine,fieldnum,lineNum,findLine,pcLine: integer;
    firstDline,topDline,botDline,firstLine,lastLine,curLine: integer;
    freeLines,oldLines: linerecp;
    sysVars: varidefp;
    dProg: statementp;
    curBlock, newDeclarations, findStmnt: statementp;
    macrodepth: integer;
    filedepth, errCount, sCursor: integer;
    curChar, maxChar, curFLine, curPage: integer;
    nodim, distancedim, timedim, angledim,
      forcedim, torquedim, veldim, angveldim: varidefp;
    fvstiffdim, mvstiffdim: nodep;
    pnode: nodep;
*)  dum2: array[1..141] of dump;
(*  smartTerminal: boolean; 
    setUp,setExpr,setCursor,dontPrint,outFilep,collect,fParse,sParse,
      eofError,endOfLine,backup,expandmacros,flushcomments,checkDims,
      shownLine: boolean;
*)  dum3: array[1..16] of boolean;
    curtoken: token;
    file1,file2,file3,file4,file5,outFile: atext;

    bpts: array [1..maxBpts] of statementp;	(* debugging crap *)
    tbpts: array [1..maxTBpts] of statementp;
    debugPdbs: array [0..10] of pdbp;
(*  nbpts,ntbpts,debugLevel: integer;
    eCurInt: pdbp;
    STLevel: integer;
*)  dum4: array[1..5] of integer;
    singleThreadMode,tSingleThreadMode: boolean;

	(* from INTERP *)
    inputLine: array [1..20] of ascii;
    talk: text;			(* for using the speech synthesizer *)
    curInt, activeInts, readQueue, allPdbs: pdbp;
    sysEnv: envheaderp;
    clkQueue: nodep;
    allEvents: eventp;
    etime: integer;		(* used by eval *)
    curtime: integer; (* who knows where this will get updated - an ast? *)
    stime: integer;		(* used for clock queue on 10 *)
    msg: messagep;		(* for AL-ARM interaction *)
    inputp: integer;		(* current offset into inputLine array above *)
    resched, running, escapeI, iSingleThreadMode: boolean;
    msgp: boolean;		(* flag set if any messages pending *)
    inputReady: boolean;

(* various constant pointers *)
    xhat,yhat,zhat,nilvect: vectorp;
    niltrans: transp;
    gpark, rpark: transp;		(* arm park positions *)

(* various device & variable pointers *)
    speedfactor: enventryp;
    garm: framep;

{ Externally defined routines: }

	(* From ALLOC *)
function newNode: nodep;					external;
procedure relNode(n: nodep);					external;

	(* From IAUX1A *)
procedure push (n: nodep);					external;
function getVar (level, offset: byte): enventryp;		external;
function getNval(n: nodep; var b: boolean): nodep;		external;
function getEvent: eventp;					external;
procedure freeEvent(e: eventp);					external;
procedure sendCmd;						external;
procedure sendTrans(tr: transp);				external;

	(* From IAUX1B *)
procedure prntStrng(length: integer; s: strngp);		external;
procedure onum(s: integer);					external;
procedure badJoints(angle: integer);				external;
procedure sleep(whenV: integer);				external;
procedure cmonDisable(c: cmoncbp);				external;
procedure ppArmError(err: errortypes; angle: integer);		external;

	(* From IAUX2A *)
procedure setVal (level, offset: byte);				external;

	(* From IAUX2B *)
procedure cmonEnable(e: enventryp);				external;

	(* From RSXMSG *)
procedure signalArm;                                         	external;

	(* Display-related Routines *)
procedure ppLine; 						external;
procedure ppOutNow; 						external;
procedure ppChar(ch: ascii); 					external;
procedure pp5(ch: c5str; length: integer); 			external;
procedure pp10(ch: cstring; length: integer); 			external;
procedure pp10L(ch: cstring; length: integer);			external;
procedure pp20(ch: c20str; length: integer); 			external;
procedure pp20L(ch: c20str; length: integer); 			external;
procedure ppInt(i: integer); 					external;
procedure ppReal(r: real); 					external;
procedure ppStrng(length: integer; s: strngp); 			external;

(* aux routines for motions: forcebits, getMechbits, moveStart, moveEnd, moveRetry *)

function forcebits(fn: nodep; var negv: boolean): integer; external;
function forcebits;
 var vec: vectorp; fbits: integer;
 begin
 fbits := XFORCE;
 negv := false;
 vec := nil;
 with fn↑.fvec↑ do
  if ntype = leafnode then vec := pcval↑.v	(* first check if axis vector *)
  else if op = vnegop then			(* or negative axis vector *)
   if arg1↑.ntype = leafnode then
    begin vec := arg1↑.pcval↑.v; negv := true end;
 if vec = yhat then fbits := YFORCE
  else if vec = zhat then fbits := ZFORCE
  else if vec <> xhat then negv := false;
 if fn↑.ftype >= torque then fbits := fbits + XMOMENT;
 forcebits := fbits;
 end;

function getMechbits: integer; external;
function getMechbits;
 var i: integer;
 begin
 with curInt↑ do
  if mech = nil then i := GARMDEV		(* default to green arm *)
   else if mech↑.ftype then
    if mech↑.dev <> nil then i := mech↑.dev↑.mech
     else i := GARMDEV				(* default to green arm *)
   else i := mech↑.mech;
 getMechbits := i;
 end;

procedure moveStart; external;
procedure moveStart;
 var cl: nodep; st: statementp;
 begin					(* enable all cmons *)
 cl := curInt↑.spc↑.clauses;
 while cl <> nil do			(* run through clauses *)
  begin			(* check for condition monitors to enable *)
  st := nil;
  with cl↑ do
   if ntype = cmonnode then
     begin if not (cmon↑.deferCm or errHandlerp) then st := cmon end
    else if (ntype = viaptnode) or (ntype = byptnode) then st := vcode
    else if (ntype = deprnode) or (ntype = apprnode) then st := code;
  if st <> nil then
    begin
    with st↑.cdef↑ do
     cmonEnable(getVar(level,offset));	(* enable cmon control block *)
    end;
  cl := cl↑.next;
  end;
 end;

procedure moveEnd; external;
procedure moveEnd;
 var cl, val: nodep; st, err: statementp; e: enventryp; ev: eventp; fr: framep;
     mechbits, errbits, angle, i: integer; errval: errortypes;
     b: boolean; ch: char; kludge: interr;

 begin	(* disable all cmons, end of motion cleanup, error checking etc. *)
 with curInt↑ do
  begin
  b := true;
  cl := spc↑.clauses;
  while cl <> nil do			(* run through clauses *)
   begin			(* check for condition monitors to disable *)
   st := nil;
   with cl↑ do
    if (ntype = cmonnode) and not errHandlerp then st := cmon
     else if (ntype = viaptnode) or (ntype = byptnode) then st := vcode
     else if (ntype = deprnode) or (ntype = apprnode) then st := code;
   if st <> nil then
     begin
     with st↑.cdef↑ do
      e := getVar(level,offset);		(* get cmon control block *)
     if e↑.c↑.running then b := false		(* is it running now? *)
      else cmonDisable(e↑.c);			(* if not disabled it *)
     end;
   cl := cl↑.next;
   end;

  if not b then sleep(30)		(* wait for cmon's to finish *)
   else
    begin				(* all cmon's are now done *)
    if mech↑.ftype then		(* get offset of device error variable *)
      if mech↑.dev <> nil then i := mech↑.dev↑.vari↑.offset + 1
       else i := 1			(* assume garm *)
     else i := mech↑.vari↑.offset + 1;
    errbits := round(sp↑.s);		(* remember error value *)
  (* Since losing Pascal doesn't have an inverse for ord *)
    kludge.i := errbits div 128;	(* recover error type *)
    errval := kludge.err;
    angle := errbits mod 128;		(* also bad angles (if applicable) *)
    errbits := errbits - angle;		(* strip out angle info *)
    setVal(0,i);			(* now pop it off stack & store it away *)
    err := nil;
    cl := spc↑.clauses;
    while cl <> nil do		(* run through clauses *)
     begin			(* check for error checker to run *)
     with cl↑ do
      if (ntype = cmonnode) and errHandlerp then
	begin
	val := getNval(cmon↑.oncond↑.eexpr,b); (* get error bits to check *)
	if errbits = round(val↑.s) then err := cmon↑.conclusion;
	if b then relnode(val);
	end;
     cl := cl↑.next;
     end;
    mode := 0;				(* get ready for next statement *)
    if errbits <> 0 then		(* was there an error? *)
      if err <> nil then
	begin				(* run error checker *)
	spc := err;
	end
       else
	begin				(* print error message *)
	if mech = nil then fr := garm
	 else if mech↑.ftype then	(* first tell what device *)
	  if mech↑.dev <> nil then fr := mech↑.dev
	   else fr := garm
	 else fr := mech;
	with fr↑.vari↑.name↑ do prntStrng(length,name);
	pp5(' -   ',3);
	ppArmError(errval,angle);
	pp20L('"P" to proceed, "R" ',20); pp20('to retry the motion ',19);
	b := (spc↑.stype <> operatetype) and (spc↑.stype <> centertype);
	if b then
	  begin pp20(', "F" to move direct',20); pp20('ly to destination   ',17) end;
	pp20L('  or B to break to d',20); pp10('ebugger   ',7);
        ppLine;
	mode := 4;
	curInt↑.next := readQueue;	(* *** should check that no other *)
	readQueue := curInt;		(* process is waiting, but... *** *)
	curInt↑.status := inputqueue;
	curInt := nil;
	resched := true;
	end
     else
      begin				(* all ok - move on to next statement *)
      spc := spc↑.next;
      end
    end
  end;
 end;

procedure moveRetry; external;
procedure moveRetry;
 var ch: ascii; ev: eventp; mechbits,i: integer; fr: framep;
     cl: nodep; b: boolean;
 begin
 with curInt↑ do
  begin
  mode := 0;
  inputReady := false;
  ch := inputLine[1];		(* what does luser want to do now? *)
  if ord(ch) > 140B then ch := chr(ord(ch)-40B);	(* convert to uppercase *)
  if ch = 'B' then running := false  (* break to debugger, proceed will retry *)
   else if ch = 'P' then spc := spc↑.next	(* move on to next statement *)
 (* else if ch = 'R' then	nothing to do *)
   else if (ch = 'F') and
	   (spc↑.stype <> operatetype) and (spc↑.stype <> centertype) then
    begin
    mode := 3;
    ev := getEvent;		(* event to use when motion finishes *)
    ev↑.count := -1;
    ev↑.waitlist := curInt;
    mechbits := getMechbits;
    b := true;
    cl := spc↑.clauses;
    while (cl <> nil) and b do		(* see if destination specified *)
     begin b := cl↑.ntype = destnode; cl := cl↑.next end;
    with msg↑ do
     begin
     cmd := movehdrcmd;
     dev := mechbits;
     bits := NULLINGCB + DURLBCB;		(* nonulling & duration *)
     evt := ev;
     dur := 5.0;				(* default time of 5 seconds *)
     sfac := 1.0;
     if mech = nil then fr := garm
      else if mech↑.ftype then
       if mech↑.dev <> nil then fr := mech↑.dev
	else fr := garm
      else fr := mech;
     if spc↑.stype = movetype then
       begin
       n := 1;				(* only one segment *)
       sendCmd;				(* send over move header *)
       cmd := movesegcmd;
       if not b then bits := Destptcb else bits := Byptcb + Destptcb;
       sendTrans(fr↑.tdest);		(* send over destination point *)
       end
      else if spc↑.stype = jtmovetype then
       begin
       n := 1;				(* only one segment *)
       i := round(fr↑.tdest↑.val[1,2]);	(* get number of joint *)
       case i of
     1:  bits := Nullingcb + Durlbcb + Joint1cb;
     2:  bits := Nullingcb + Durlbcb + Joint2cb;
     3:  bits := Nullingcb + Durlbcb + Joint3cb;
     4:  bits := Nullingcb + Durlbcb + Joint4cb;
     5:  bits := Nullingcb + Durlbcb + Joint5cb;
     6:  bits := Nullingcb + Durlbcb + Joint6cb;
	end;
       sendCmd;				(* send over move header *)
       cmd := movesegcmd;
       if not b then bits := Destptcb else bits := Byptcb + Destptcb;
       sendCmd;
       t[i] := fr↑.tdest↑.val[1,1];	(* send over joint value *)
       sendCmd;
       end
      else
       begin
       pos := fr↑.sdest;
       if pos < 0.0 then
	 begin				(* no dest specified *)
	 pos := 0.0;
	 if spc↑.stype = opentype then bits := 3 else bits := 1;
  (* *** need to set DURLBCB too??? *** *)
	 end
	else
	 bits := bits + DESTPTCB;	(* indicate specifying opening *)
       if mechbits = VISEDEV then
	 begin
	 cmd := operatecmd;		(* vise uses an operate command *)
	 v2 := 0.0;			(* no stop wait time *)
	 end;
       sendCmd;
       end;
     end;
    if mechbits <> VISEDEV then signalArm;	(* start it up *)
    curInt↑.status := devicewait; 	(* don't for simulation version *)
    curInt := nil;
    resched := true;			(* swap someone else in *)
    end;
  end;
 end;